Ajuda exercício Lógica de programação em Portugol

Programação
#1

Olá,

Estou com uma dificuldade, estou estudando validações, porém o loop fica infinito, mesmo ao digitar N ao perguntar “Quer continuar”, para sair, e não estou conseguindo encontrar o erro.

programa
{
	inclua biblioteca Texto --> txt
	inclua biblioteca Tipos --> ti
	
	funcao inicio()
	{
		//declarando variaveis
		inteiro c=0, idade
		cadeia nome, teclado
		caracter resp=' '
		
		//entrada de dados
		escreva("{ EXERCÍCIO 053 - Pessoas Validadas }\n")
		faca{
			enquanto(verdadeiro){
		
				escreva("-----------------------------------\n")
				escreva("\t     Pessoa ", (c+1), "\n")
				escreva("-----------------------------------\n")
				enquanto(verdadeiro){
					escreva("Nome: ")
					leia(nome)
					se(txt.numero_caracteres(nome)>=3){
						pare
					}senao{
						escreva("<<ERRO>> ... O nome deve ter pelo menos 3 letras!\n")
					}
				}
				enquanto(verdadeiro){
					escreva("Idade: ")
					leia(teclado)
					se(ti.cadeia_e_inteiro(teclado, 10)){
						idade = ti.cadeia_para_inteiro(teclado, 10)
						se(idade>=0 e idade<=130){
							pare					
						}senao{
							escreva("Idade inválida! Coloque um valor entre 0 e 130.\n")
						}
					}senao{
						escreva("A idade deve ser um número inteiro!\n")
					}
				}
			
				c++
				enquanto(verdadeiro){
					escreva("Quer continuar? [S/N] ")
					leia(resp)
					se(resp == 'N' ou resp == 'n' ou resp == 's' ou resp == 'S'){
						pare
					}senao{
						escreva("<<ERRO>> ... DIGITE [S] para SIM e [N] para NÂO.\n")
					}
				}
			}				
		}enquanto(resp == 'S' ou resp == 's')
		//resultados finais
		escreva("=-=-=-=-=-=-=-=-=-=Resultado=-=-=-=-=-=-=-=-=-=")
		escreva("Ao todo, você cadastrou ", c, " pessoas.")
	}
}
#2

A tua resposta nunca vai ser avaliada para verificar se sai ou não do “faca” porque nunca sais deste “enquanto(verdadeiro)”
Este enquanto está a mais e está a provocar os teus problemas.

#3

Muito obrigado pelo retorno, realmente esse enquanto estava sobrando, retirei ele e funcionou. No inicio do exercício ele fazia sentido para mim kkkk. :rofl:
Tudo de bom para você, mais uma vez obrigado!